摘要：本文首發(fā)于深入淺出區(qū)塊鏈社區(qū)原文鏈接如何通過以太坊智能合約來進(jìn)行眾籌原文已更新，請(qǐng)讀者前往原文閱讀前面我們有兩遍文章寫了如何發(fā)行代幣，今天我們講一下如何使用代幣來公開募資，即編寫一個(gè)募資合約。

本文首發(fā)于深入淺出區(qū)塊鏈社區(qū)
原文鏈接:如何通過以太坊智能合約來進(jìn)行眾籌（ICO）原文已更新，請(qǐng)讀者前往原文閱讀

前面我們有兩遍文章寫了如何發(fā)行代幣，今天我們講一下如何使用代幣來公開募資，即編寫一個(gè)募資合約。

本文所講的代幣是使用以太坊智能合約創(chuàng)建，閱讀本文前，你應(yīng)該對(duì)以太坊、智能合約有所了解，如果你還不了解，建議你先看以太坊是什么

先簡(jiǎn)單說下眾籌的概念：一般是這樣的，我一個(gè)非常好的想法，但是我沒有錢來做這事，于是我把這個(gè)想法發(fā)給大家看，說：我做這件事需要5百萬，大家有沒有興趣投些錢，如果大家在30天內(nèi)投夠了5百萬我就開始做，到時(shí)大家都是原始股東，如果募資額不到5百萬，大家投的錢就還給大家。

現(xiàn)在ICO眾籌已經(jīng)被各路大佬拿來割韭菜而被玩壞了（不管有無達(dá)標(biāo)，都把錢卷走）。

其實(shí)區(qū)塊鏈技術(shù)本事非常適合解決眾籌的信任問題，借助于智能合約，可以實(shí)現(xiàn)當(dāng)募資額完成時(shí)，募資款自動(dòng)打到指定賬戶，當(dāng)募資額未完成時(shí)，可退款。這個(gè)過程不需要看眾籌大佬的人品，不用依靠第三方平臺(tái)信用擔(dān)保。

傳統(tǒng)的眾籌在參與之后通常不容易交易（參與之后無法轉(zhuǎn)給其他人），而通過用代幣來參與眾籌，則很容易進(jìn)行交易，眾籌的參與人可隨時(shí)進(jìn)行買賣，待眾籌項(xiàng)目實(shí)施完成的時(shí)候，完全根據(jù)代幣持有量進(jìn)行回饋。

舉個(gè)例子說明下，大家會(huì)更容易理解，有這一個(gè)眾籌：A有技術(shù)做一個(gè)能監(jiān)測(cè)健康的指環(huán)，為此向公眾募資200百萬，募資時(shí)100塊對(duì)應(yīng)一個(gè)代幣，約定在指環(huán)上市之后，代幣的持有人可以用一個(gè)代幣來兌換一個(gè)指環(huán)。而指環(huán)的研發(fā)周期是一年，因此在指環(huán)還未上市的一年里，眾籌的參與人可以隨時(shí)交易所持有的代幣。

接下來就看看如何實(shí)現(xiàn)一個(gè)眾籌智能合約。

pragma solidity ^0.4.16;

interface token {
    function transfer(address receiver, uint amount);
}

contract Crowdsale {
    address public beneficiary;  // 募資成功后的收款方
    uint public fundingGoal;   // 募資額度
    uint public amountRaised;   // 參與數(shù)量
    uint public deadline;      // 募資截止期

    uint public price;    //  token 與以太坊的匯率 , token賣多少錢
    token public tokenReward;   // 要賣的token

    mapping(address => uint256) public balanceOf;

    bool fundingGoalReached = false;  // 眾籌是否達(dá)到目標(biāo)
    bool crowdsaleClosed = false;   //  眾籌是否結(jié)束

    /**
    * 事件可以用來跟蹤信息
    **/
    event GoalReached(address recipient, uint totalAmountRaised);
    event FundTransfer(address backer, uint amount, bool isContribution);

    /**
     * 構(gòu)造函數(shù), 設(shè)置相關(guān)屬性
     */
    function Crowdsale(
        address ifSuccessfulSendTo,
        uint fundingGoalInEthers,
        uint durationInMinutes,
        uint finneyCostOfEachToken,
        address addressOfTokenUsedAsReward) {
            beneficiary = ifSuccessfulSendTo;
            fundingGoal = fundingGoalInEthers * 1 ether;
            deadline = now + durationInMinutes * 1 minutes;
            price = finneyCostOfEachToken * 1 finney;
            tokenReward = token(addressOfTokenUsedAsReward);   // 傳入已發(fā)布的 token 合約的地址來創(chuàng)建實(shí)例
    }

    /**
     * 無函數(shù)名的Fallback函數(shù)，
     * 在向合約轉(zhuǎn)賬時(shí)，這個(gè)函數(shù)會(huì)被調(diào)用
     */
    function () payable {
        require(!crowdsaleClosed);
        uint amount = msg.value;
        balanceOf[msg.sender] += amount;
        amountRaised += amount;
        tokenReward.transfer(msg.sender, amount / price);
        FundTransfer(msg.sender, amount, true);
    }

    /**
    *  定義函數(shù)修改器modifier（作用和Python的裝飾器很相似）
    * 用于在函數(shù)執(zhí)行前檢查某種前置條件（判斷通過之后才會(huì)繼續(xù)執(zhí)行該方法）
    * _ 表示繼續(xù)執(zhí)行之后的代碼
    **/
    modifier afterDeadline() { if (now >= deadline) _; }

    /**
     * 判斷眾籌是否完成融資目標(biāo)， 這個(gè)方法使用了afterDeadline函數(shù)修改器
     *
     */
    function checkGoalReached() afterDeadline {
        if (amountRaised >= fundingGoal) {
            fundingGoalReached = true;
            GoalReached(beneficiary, amountRaised);
        }
        crowdsaleClosed = true;
    }


    /**
     * 完成融資目標(biāo)時(shí)，融資款發(fā)送到收款方
     * 未完成融資目標(biāo)時(shí)，執(zhí)行退款
     *
     */
    function safeWithdrawal() afterDeadline {
        if (!fundingGoalReached) {
            uint amount = balanceOf[msg.sender];
            balanceOf[msg.sender] = 0;
            if (amount > 0) {
                if (msg.sender.send(amount)) {
                    FundTransfer(msg.sender, amount, false);
                } else {
                    balanceOf[msg.sender] = amount;
                }
            }
        }

        if (fundingGoalReached && beneficiary == msg.sender) {
            if (beneficiary.send(amountRaised)) {
                FundTransfer(beneficiary, amountRaised, false);
            } else {
                //If we fail to send the funds to beneficiary, unlock funders balance
                fundingGoalReached = false;
            }
        }
    }
}

在部署這個(gè)合約之前，我們需要先部署一個(gè)代幣合約，請(qǐng)參考一步步教你創(chuàng)建自己的數(shù)字貨幣。

創(chuàng)建眾籌合約我們需要提供一下幾個(gè)參數(shù)：

ifSuccessfulSendTo： 募資成功后的收款方（其實(shí)這里可以默認(rèn)為合約創(chuàng)建者）
fundingGoalInEthers： 募資額度， 為了方便我們僅募3個(gè)ether
durationInMinutes： 募資時(shí)間
finneyCostOfEachToken 每個(gè)代幣的價(jià)格, 這里為了方便使用了單位finney及值為：1 （1 ether = 1000 finney）
addressOfTokenUsedAsReward： 代幣合約地址。
如：

本文使用的參數(shù)為：

"0xc6f9ea59d424733e8e1902c7837ea75e20abfb49",3, 100, 1,"0xad8972e2b583f580fc52f737b98327eb65d08f8c"

參與人投資的時(shí)候?qū)嶋H購買眾籌合約代幣，所以需要先向合約預(yù)存代幣，代幣的數(shù)量為：募資額度 / 代幣的價(jià)格 ， 這里為：3 * 1000/1 = 3000 （當(dāng)能也可以大于3000）。

向合約預(yù)存代幣可以使用myetherwallet錢包，或在remix中重新加載代幣合約，執(zhí)行代幣合約tranfer()函數(shù)進(jìn)行代幣轉(zhuǎn)賬，轉(zhuǎn)賬的地址就是我們創(chuàng)建合約的地址。如使用myetherwallet轉(zhuǎn)賬如圖：

投資人向眾籌合約轉(zhuǎn)賬（發(fā)送以太幣）即是參與眾籌行為，轉(zhuǎn)賬時(shí)，會(huì)執(zhí)行Fallback回退函數(shù)（即無名函數(shù)）向其賬戶打回相應(yīng)的代幣。

safeWithdrawl() 可以被參與人或收益人調(diào)用，如果融資不達(dá)標(biāo)參與人可收回之前投資款，如果融資達(dá)標(biāo)收益人可以拿到所有的融資款。

上面是一個(gè)很正規(guī)的募資合約。接下來講兩個(gè)募資合約的擴(kuò)展，如何實(shí)現(xiàn)無限募資合約及割韭菜合約。
這部分內(nèi)容獨(dú)家發(fā)布在我的小專欄區(qū)塊鏈技術(shù)

如何創(chuàng)建代幣發(fā)行代幣，現(xiàn)在也錄制了對(duì)應(yīng)的視頻教程:通過代幣學(xué)以太坊智能合約開發(fā)
目前我們也在招募體驗(yàn)師，可以點(diǎn)擊鏈接了解。

如果你在學(xué)習(xí)中遇到問題，歡迎到我的知識(shí)星球提問，作為星球成員福利，成員可加入?yún)^(qū)塊鏈技術(shù)付費(fèi)交流群。

Create a crowdsale

? 深入淺出區(qū)塊鏈 - 系統(tǒng)學(xué)習(xí)區(qū)塊鏈，打造最好的區(qū)塊鏈技術(shù)博客。

? 我的知識(shí)星球為各位解答區(qū)塊鏈技術(shù)問題，歡迎加入討論。

? 關(guān)注公眾號(hào)“深入淺出區(qū)塊鏈技術(shù)”第一時(shí)間獲取區(qū)塊鏈技術(shù)信息。