摘要：合約編寫可以看出合約需要實(shí)現(xiàn)用戶投注生成隨機(jī)數(shù)發(fā)放獎(jiǎng)勵(lì)獎(jiǎng)池余額查詢的功能，接下來編寫我們的合約代碼?？偨Y(jié)當(dāng)前隨機(jī)數(shù)的實(shí)現(xiàn)通過鏈上信息生成，這種生成隨機(jī)數(shù)的方式容易受到不誠實(shí)的節(jié)點(diǎn)攻擊。

導(dǎo)讀：
本文旨在引導(dǎo)對(duì) DApp 開發(fā)感興趣的開發(fā)者，構(gòu)建一個(gè)基于以太坊去中心化應(yīng)用，通過開發(fā)一款功能完備的競猜游戲，邁出 DApp 開發(fā)的第一步，通過實(shí)例講解 Solidity 語言的常用語法，以及前端如何與智能合約進(jìn)行交互。
如果正在閱讀的你，從未接觸過 DApp 開發(fā)也不要緊，可以先閱讀【區(qū)塊鏈上編程：DApp開發(fā)簡介】進(jìn)行前置知識(shí)補(bǔ)充。

隨著加密貓、FOMO3D 等游戲的火爆，去中心化應(yīng)用在游戲領(lǐng)域遍地開花，下面就帶著大家一起開發(fā)一款簡單有趣的 DApp 游戲，幫助大家熟悉 DApp 開發(fā)。

本 DApp 實(shí)現(xiàn)的合約功能：用戶從 0-6 的數(shù)字中，任意組合三位數(shù)進(jìn)行投注，合約計(jì)算出 3 位隨機(jī)數(shù)，根據(jù)隨機(jī)數(shù)的組合規(guī)則分別給予用戶不同倍數(shù)的獎(jiǎng)勵(lì)，如隨機(jī)數(shù)為 AAA ，A 等于 6 則獎(jiǎng)勵(lì)至少 20 倍投注金額，即獎(jiǎng)池所有余額；A 不等于 6 則獎(jiǎng)勵(lì) 5 倍投注金額；隨機(jī)數(shù)為 AAB，則獎(jiǎng)勵(lì) 2 倍投注金額；隨機(jī)數(shù)為 ABC 則不獎(jiǎng)勵(lì)，同時(shí)用戶可查看獎(jiǎng)池余額和個(gè)人投注記錄。

可以看出合約需要實(shí)現(xiàn)用戶投注、生成隨機(jī)數(shù)、發(fā)放獎(jiǎng)勵(lì)、獎(jiǎng)池余額查詢的功能，接下來編寫我們的合約代碼。

新建Lottery.sol合約文件，聲明合約版本，^表示合約編譯版本為 0.4.0 至 0.5.0（不含 0.5.0）。

pragma solidity ^0.4.0;

定義合約基本內(nèi)容，同時(shí)聲明最低投注金額。

contract Lottery {
  uint public betMoney = 10 finney;
}

生成隨機(jī)數(shù)，通過區(qū)塊難度block.difficulty和內(nèi)置函數(shù)keccak256生成隨機(jī)數(shù)，在EVM中常用的數(shù)據(jù)存儲(chǔ)位置：memory、storage，函數(shù)的參數(shù)、返回值默認(rèn)存儲(chǔ)在memory中，狀態(tài)變量默認(rèn)存儲(chǔ)在storage中，我們可以通過聲明memory、storage改變默認(rèn)存儲(chǔ)位置，兩者的存儲(chǔ)都需要消耗gas，但storage的開銷遠(yuǎn)大于memory。

contract Lottery {
  ...
  function generateRandomNumber() private view returns(uint[]) {
    uint[] memory dices = new uint[](3);
    for (uint i = 0; i < 3; i++) {
      dices[i] = uint(keccak256(abi.encodePacked(block.difficulty, now, i))) % 6 + 1;
    }
    return dices;
  }
  ...
}

獲取合約余額，address類型比較重要的成員屬性主要有balance、transfer，分別為獲取地址余額、轉(zhuǎn)移eth至該地址，默認(rèn)eth單位是wei。

contract Lottery {
  ...
  function getBankBalance() public view returns(uint) {
    return address(this).balance;
  }
  ...
}

用戶投注，投注方法需要使用payable關(guān)鍵字描述，用來表示可以接收eth；通過msg.sender和msg.value獲得交易發(fā)送者地址和當(dāng)前交易附帶的eth。通常使用require來校驗(yàn)外部輸入?yún)?shù)，當(dāng)判定條件為false時(shí)，則會(huì)將剩余的gas退回，同時(shí)回滾交易；assert則用來處理合約內(nèi)部的邏輯錯(cuò)誤，當(dāng)錯(cuò)誤發(fā)生時(shí)會(huì)消耗掉所有gas，同時(shí)回滾交易。

contract Lottery {
  ...
  function bet() public payable {
    uint amount = msg.value;
    require(amount >= betMoney, "bet money not less than 10 finney");
    require(address(this).balance >= amount * 20, "contract money not enough to pay reward");

    uint[] memory dices = generateRandomNumber();
    require(dices.length == 3, "dices illegal");

    address addr = msg.sender;
    bool isReward = false;
    uint reward = 0;

    if ((dices[0] == dices[1]) && (dices[1] == dices[2]) && (dices[0] == 6)) {
      isReward = true;
      reward = address(this).balance;
    } else if ((dices[0] == dices[1]) && (dices[1] == dices[2]) && (dices[0] != 6)) {
      isReward = true;
      reward = amount * 5;
    } else if ((dices[0] == dices[1]) || (dices[0] == dices[2]) || (dices[1] == dices[2])) {
      isReward = true;
      reward = amount * 2;
    }

    if (isReward) {
      addr.transfer(reward);
    }
  }
  ...

定義事件，通過合約內(nèi)部觸發(fā)事件，web3 監(jiān)聽到事件回調(diào)進(jìn)行相應(yīng)邏輯處理，從而進(jìn)行頁面 UI 更新；同時(shí)前端也可以通過對(duì)應(yīng)事件名稱獲取日志信息。

contract Lottery {
  ...
  event BetList(
    address addr,
    uint amount,
    bool isReward,
    uint reward,
    uint[] dices
  );

  function bet() public payable {
    ...
    emit BetList(addr, amount, isReward, reward, dices);
  }
  ...

至此，我們已經(jīng)寫完了合約代碼，前端頁面實(shí)現(xiàn)就不在此贅述，主要介紹如何使用 web3 與合約交互，這里使用到的 web3 版本是 1.0，web3 1.0 和 0.2x.x 的 API 調(diào)用方式差別較大，1.0 的 API 支持異步調(diào)用。

安裝 Metamask 瀏覽器插件后，會(huì)在瀏覽器頁面內(nèi)注入一個(gè) web3 實(shí)例。檢測頁面中是否存在 web3 實(shí)例，如果不存在則連接自己的實(shí)例。

import Web3 from "web3";

if (typeof web3 !== "undefined") {
  web3 = new Web3(web3.currentProvider);
} else {
  web3 = new Web3(new Web3.providers.HttpProvider(NODE_NRL));
}

傳入合約 ABI，合約地址，實(shí)例化合約對(duì)象。

this.contract = new web3.eth.Contract(
  CONTRACT_ABI,
  CONTRACT_ADDR,
);

調(diào)用合約中的投注方法，通過try catch可以捕獲到 Metamask 彈窗取消交易操作。

userBet = async () => {
  try {
    await this.contract.methods
      .bet(
        ...
      )
      .send({
        from: ACCOUNT,
        value: MONEY,
      });
  } catch (error) {
    ...
  }
}

查詢記錄的日志，可以通過指定事件名稱、區(qū)塊高度及過濾條件來進(jìn)行日志查詢，值得注意的是，在合約內(nèi)不能查詢到日志信息。

queryEvent = async () => {
  const event = await this.contract.getPastEvents(
    EVENT_NAME,
    {
      filter: {},
      fromBlock: 0,
      toBlock: "latest",
    }
  )
}

比如修改用戶投注金額及充值這類敏感操作，就需要管理員的權(quán)限來進(jìn)行操作。同樣地，我們也可以拓展贊助商的功能，通過充值獎(jiǎng)池的累計(jì)金額排名來展示贊助商的廣告，這里就不做展開了。

定義修飾器，在構(gòu)造函數(shù)里設(shè)置管理員地址，將創(chuàng)建合約的賬戶設(shè)置為管理員。

contract Lottery {
  ...
  address public owner;

  modifier onlyOwner() {
    require(owner == msg.sender);
    _;
  }

  constructor() public {
    owner = msg.sender;
  }
  ...
}

實(shí)現(xiàn)修改投注金額的功能，僅管理員賬戶可觸發(fā)。

contract Lottery {
  ...
  function setBetMoney(uint _betMoney) public onlyOwner {
    betMoney = _betMoney;
  }

  function deposit() public payable onlyOwner {}
  ...
}

當(dāng)前隨機(jī)數(shù)的實(shí)現(xiàn)通過鏈上信息生成，這種生成隨機(jī)數(shù)的方式容易受到不誠實(shí)的節(jié)點(diǎn)攻擊。下一篇文章將通過多個(gè)實(shí)例介紹相應(yīng)的第三方工具庫的使用（Oricalize、SafeMath、OpenZepplin），生成安全的隨機(jī)數(shù)。

Solidity

Web3js

Cryptozombies

Coursetro

前置文章：

在區(qū)塊鏈上編程：DApp 開發(fā)簡介

文 / ielapp
一個(gè)簡單的程序員
編 / 熒聲

本文已由作者授權(quán)發(fā)布，版權(quán)屬于創(chuàng)宇前端。歡迎注明出處轉(zhuǎn)載本文。本文鏈接：https://knownsec-fed.com/2018...

想要訂閱更多來自知道創(chuàng)宇開發(fā)一線的分享，請(qǐng)搜索關(guān)注我們的微信公眾號(hào)：創(chuàng)宇前端（KnownsecFED）。歡迎留言討論，我們會(huì)盡可能回復(fù)。

歡迎點(diǎn)贊、收藏、留言評(píng)論、轉(zhuǎn)發(fā)分享和打賞支持我們。打賞將被完全轉(zhuǎn)交給文章作者。

感謝您的閱讀。